基于JTAG的DSP外部FLASH在線(xiàn)編程與引導技術(shù)

　　在以DSP為核心的數字信號處理系統中，通常將可執行代碼存放在非易失性存儲器，在系統加電或復位時(shí)通過(guò)DSP的引導加載（Boot Loader）機制將該轉換到高速存儲器中執行。AD公司出品的ADSP SHARC系列DSP內部的非易失性存儲器因其資源有限，必須在外部加以擴展。FLASH存儲器具有容量大、單電源供電和可在線(xiàn)編程的特點(diǎn)，是一種非常理想的存儲器。

若采用燒錄器對FLASH存儲器進(jìn)行編程，則在修改程序時(shí)必須拔插器件，而某些表貼封裝（如PLCC封裝和TSOP封裝）的器件又需要專(zhuān)用的轉接插座，這使得程序的調試和參數的修改非常繁瑣，而且容易對器件造成物理?yè)p傷。采用在線(xiàn)編程的方式對FLASH存儲器進(jìn)行操作，可以克服上述問(wèn)題，為調試者提供了極大的方便。本文以ADSP-21065L外部擴展的FLASH存儲器AT29LV020為對象，在Visual DSP++3.5環(huán)境中通過(guò)JTAG仿真器運行一段程序，將可引導代碼在線(xiàn)燒錄到FLASH中，并實(shí)現系統的引導。

1 在線(xiàn)編程與引導系統

本系統以ADSP-21065L及外部的FLASH存儲器AT29LV020為核心，由DSP控制FLASH存儲器的擦除和讀寫(xiě)。

AT29LV020是用單電源3.3V供電的低功耗FLASH存儲器，容量是MB（256K×8），8位數據總線(xiàn)，18位地址總線(xiàn)。該芯片以扇區（SECTOR）為基本的編程單元，共有1024個(gè)扇區，每個(gè)扇區包含256個(gè)字節。芯片的存儲空間中包含兩個(gè)引導區，分別是最低8K（0x00000～0x01FFF）和最高8位（0x3E000～0x3FFFF）的引導區。

系統引導時(shí)，DSP將FLASH作為普通的外部數據存儲器，通過(guò)DMA方式訪(fǎng)問(wèn)。ADSP-21065L的外部地址空間為0x00020000～0x03FFFFFF。FLASH的物理地址（ADD）對于DSP來(lái)說(shuō)就是（0x0002000+ADD）。整片AT239LV020占據ADSP-21065L的外部地址空間范圍為0x00020000～0x0005FFFF，這段空間屬于Bank0。訪(fǎng)問(wèn)該段空間時(shí)，DSP引腳MS0有效。引導時(shí)，DSP引腳BMS有效。所以，使用MS0和BMS的組合作為FLASH的片選信號。DSP與FLASH的連接如圖1所示。

2 DSP可引導文件的創(chuàng )建

在線(xiàn)編程的過(guò)程如下：

（1） 創(chuàng )建一個(gè)適合FLASH存儲器的引導程序文件A；

（2） 在Visual DSP++3.5環(huán)境中編寫(xiě)一個(gè)FLASH的操作程序，創(chuàng )建一個(gè)可執行的“.DXE”文件B；

（3） 通過(guò)基于JTAG的Emulator將B下載到DSP中執行，將A文件寫(xiě)入FLASH中。

下面介紹如何在Visual DSP++3.5的開(kāi)發(fā)環(huán)境中有建一個(gè)可以引導的文件。該文件就是通過(guò)JTAG寫(xiě)入FLASH中的目標文件。具體步驟如下：

（1） 創(chuàng )建一個(gè)將要寫(xiě)入FLASH的源程序，在Visual DSP++環(huán)境中直接通過(guò)Emulator下載到DSP中執行，驗證程序的正確性。

（2） 打開(kāi)菜單Droject→Project Ontions…， 在Project標簽的頁(yè)面里，選擇Type為L(cháng)oader File；在Load標簽的頁(yè)面里，選擇Boot Mode為Prom，選擇Boot Format為ASCII， 并為將要創(chuàng )建的.LDR文件指定名稱(chēng)。

（3） 重新編譯工程，在工程目錄中得 到一個(gè)載入文件*.LDR。

至此，一個(gè)可引導的文件就創(chuàng )建成功了。文件文件的格式如下：

……

0x1254

0xCDF3

0x256C

……

該文件有n行，每行為一個(gè)雙字節的16進(jìn)制數?？紤]到FLASH的數據總線(xiàn)是8位，在寫(xiě)入之前，必須將每行分成兩個(gè)單字節的16進(jìn)制數。

3 FLASH在線(xiàn)編程的實(shí)現

3．1 FLASH扇區編程的實(shí)現

AT29LV020的操作包括扇區編程、整片擦除、讀芯片ID、退出讀芯片ID、引導區加鎖等，這里關(guān)心的主要是扇區編程。

扇區是AT29LV020編程的最小操作單位，每次編程操作時(shí)，目標扇區的256個(gè)字節同時(shí)進(jìn)行。在DSP的寫(xiě)指令字序列的作用下，同一個(gè)扇區的256個(gè)字節被寫(xiě)入FLASH內部的緩沖區，然后FLASH自動(dòng)啟動(dòng)編程操作。DSP向緩沖區寫(xiě)入同一個(gè)扇區的數據時(shí)，數據的寫(xiě)入順序是任意的，但是相鄰的寫(xiě)信號間隔不能大于150μs，否則將被視為寫(xiě)入操作完成，編程過(guò)程立刻啟動(dòng)，而扇區內沒(méi)有寫(xiě)入內容的地址將全部編程的為FF。完成一個(gè)扇區的編程最多只需要20ms。編程過(guò)程啟動(dòng)后首先會(huì )自動(dòng)擦除需要編程的扇區，所以在編程前并不需要對扇區進(jìn)行單獨的擦除操作。

為了防止FLASH中的內容被誤操作或者其它操作修改，FLASH默認為寫(xiě)保護狀態(tài)。每次對扇區進(jìn)行編程前必須寫(xiě)入一個(gè)命令序列，才可以向FLASH的緩沖區寫(xiě)入數據，進(jìn)而啟動(dòng)編程。編程結束后，FLASH自動(dòng)恢復到寫(xiě)保護狀態(tài)。

一個(gè)扇區編程是否結束，可以通過(guò)以下三種方法判斷：

（1） 反復讀最后寫(xiě)入的地址的內容，如果編程沒(méi)有結束，讀到數據的最高位與最后寫(xiě)入的數據的最高位始終互為補碼；編程結束后，讀取的數據與最后寫(xiě)入的數據的最高位始終互為補碼；編程結束后，讀到的數據與最后寫(xiě)入的數據相等。

（2） 反復讀任意某個(gè)地址的內容，如果編程沒(méi)有結束， 每次讀操作都會(huì )導致次高位發(fā)生跳變；編程結束后，讀到的結果就是寫(xiě)入該地址的實(shí)際數據。

（3） 寫(xiě)完一個(gè)扇區后延時(shí)20ms，作為扇區編程結束的依據。

3.2 FLASH文件在線(xiàn)編程的實(shí)現

考慮到AT29LV020的最小編程單位為一個(gè)扇區，首先應該將待編程的文件分割為若干個(gè)256字節的編程單元，對于最后的一個(gè)單元，無(wú)論是否夠256字節，都無(wú)需理會(huì )，仍舊按照一個(gè)扇區處理。

假設待編程的文件名為filename.ldr，采用編程語(yǔ)言編寫(xiě)軟件時(shí)，使用變量定義：

.var f_data[]=”filename.ldr”;

緩沖區f_data[]的首址指向filename.ldr的首行，f_data的每個(gè)元素都對應文件的一行。由于創(chuàng )建的引導程序文件每行數據都是16位的，包含兩個(gè)8位字節，所以必須將其分解為兩部分后分別寫(xiě)入FLASH。

軟件的流程如圖3所示。

4 測試實(shí)現

下面是將文件寫(xiě)入FLASH的完整程序，在實(shí)際中已經(jīng)調試成功。通過(guò)該程序將一段閃燈代碼blink.ldr寫(xiě)入FLASH中，復位后，被寫(xiě)入的代碼自動(dòng)加載到DSP中執行。在編程過(guò)程中，ADSP-21065L的FLAG10引腳輸出周期為40ms的方波；編程結束后，FLAG8輸出周期為40ms的方波。

//宏定義與變量初始化

#define f_size 1572 //文件的行數

#define mem_offset 0x020000 //FLASH的地址偏移

#define u_mem1_a 0x025555 //命令字寫(xiě)入地址1

#define u_mem2_a 0x022AAA //命令字寫(xiě)入地址2

#includedef21065L.h>

.section/dm seg_fout;

.var f_data[]=”blink,ldr” //待寫(xiě)入的代碼文件

.section/dm seg_dmda;

.var d_byte;

.var addr;

.var line_num=0; //當前扇區已寫(xiě)入行數

.var byte_size; //待寫(xiě)入代碼字節數-1

.var counter=0; //延時(shí)的計數值

//復位中斷

.section/pm pm_rsti;

nop;

jump start;

nop;

//以下是主程序

.section/pm seg_pmco;

start:

nop;

bit clr mode1 0x00001000; //屏蔽所有中斷

IRPTL=0x0; //清除未響應中斷

r0=0x0050; //設置FLAG10和

dm(IOCTL)=r0; //FLAG8為輸出引腳

program:

i0=f_data;

r2=0x0; //已經(jīng)寫(xiě)入的字節數-1

r3=f_size;

r4=r3+r3;

r4=r4-1;

dm(byte_size)=r4;

r6=dm(line_num);

r7=0;

comp(r6,r7); //判斷是否為新的扇區

if ne jump sect_load; //不是，則直接向FLASH緩沖區寫(xiě)入字節

sect_ulock: //是，首先寫(xiě)命令字序列

r12=0xAA;

dm(u_mem1_a)=r12;

r12=0x55;

dm(u_mem2_a)=r12;

r12=0xA0;

dm(u_mem1_a)=r12;

sect_load:

r0=dm(i0,1); //讀取一行數據

r1=fext r0 by 0:8; //獲得低字節

dm(d_byte)=r1;

dm(addr)=r2;

call load_byte; //向FLASH寫(xiě)入低字節

r2=r2+1;

r1=fext r0 by 8:8; //獲得高字節

dm(d_byte)=r1;

dm(addr)=r2;

call loade_byte; //向FLASH寫(xiě)入高字節

r8=dm(byte_size);

comp(r2,r8); //判斷文件是否全部寫(xiě)完

if eq jump done; //是，則結束

r6=dm(line_num); //否，判斷扇區是否結束

r6=r6+1;

dm(line_num)=r6;

r7=128;

comp(r6,r7);

if lt jump prog_loop; 否，繼續向該扇區寫(xiě)數據

sect_done: //是，等待20ms

nop;

call wait_DQ7;

ustat2=dm(IOSTAT);

bit tg1 ustat2 FLG10O;

dm(IOSTAT)=ustat2; //翻轉FLAG10

r6=0;

dm(line_num)=r6;

r2=r2+1;

jump sect_ulock; //開(kāi)始向新扇區寫(xiě)數據

prog_loop:

r2=r2+1;

jump sect_load;

done: //編程結束

nop;

call wait_DQ7;

ustat2=dm(IOSTAT);

bit tg1 ustat2 FLG8O; //翻轉FLAG8

dm(IOSTAT)=ustat2;

jump done;

load_byte: //寫(xiě)字節子程序

i4=dm(addr);

m4=mem_offset;

r12=dm(d_byte);

dm(m4,i4)=r12;

rts;

nop

wait_DQ7: //20ms延時(shí)子程序

r0=dm(counter);

r0=r0+1;

dm(counter)=r0;

r1=0x59000;

comp(r0,r1);

if lt jump wait_DQ7;

r0=0;

dm(counter)=r0;

rts;

nop;

上面的程序是針對由ADSP-21065L和AT29LV020構成的磁懸浮數字控制系統編寫(xiě)的，可行性與可靠性已經(jīng)在實(shí)際應用中得到驗證。該程序具有良好的可移植性，秒作修改即可用于類(lèi)似的在線(xiàn)編程系統，具有較強的實(shí)用價(jià)值。