uC/OS-II在51單片機上的移植1

結語(yǔ)：μC/OS-II具有免費、簡(jiǎn)單、可靠性高、實(shí)時(shí)性好等優(yōu)點(diǎn)，但也有缺乏便利開(kāi)發(fā)環(huán)境等缺點(diǎn)，尤其不像商用嵌入式系統那樣得到廣泛使用和持續的研究更新。但開(kāi)放性又使得開(kāi)發(fā)人員可以自行裁減和添加所需的功能，在許多應用領(lǐng)域發(fā)揮著(zhù)獨特的作用。當然，是否在單片機系統中嵌入μC/OS-II應視所開(kāi)發(fā)的項目而定，對于一些簡(jiǎn)單的、低成本的項目來(lái)說(shuō)，就沒(méi)必要使用嵌入式操作系統了。

uC/OS-II原理：
uCOSII包括任務(wù)調度、時(shí)間管理、內存管理、資源管理（信號量、郵箱、消息隊列）四大部分，沒(méi)有文件系統、網(wǎng)絡(luò )接口、輸入輸出界面。它的移植只與4個(gè)文件相關(guān)：匯編文件（OS_CPU_A.ASM）、處理器相關(guān)C文件（OS_CPU.H、OS_CPU_C.C）和配置文件（OS_CFG.H）。有64個(gè)優(yōu)先級，系統占用8個(gè)，用戶(hù)可創(chuàng )建56個(gè)任務(wù)，不支持時(shí)間片輪轉。它的基本思路就是 “近似地每時(shí)每刻總是讓優(yōu)先級最高的就緒任務(wù)處于運行狀態(tài)” 。為了保證這一點(diǎn)，它在調用系統API函數、中斷結束、定時(shí)中斷結束時(shí)總是執行調度算法。原作者通過(guò)事先計算好數據，簡(jiǎn)化了運算量，通過(guò)精心設計就緒表結構，使得延時(shí)可預知。任務(wù)的切換是通過(guò)模擬一次中斷實(shí)現的。
uCOSII工作核心原理是：近似地讓最高優(yōu)先級的就緒任務(wù)處于運行狀態(tài)。
操作系統將在下面情況中進(jìn)行任務(wù)調度：調用API函數(用戶(hù)主動(dòng)調用)，中斷(系統占用的時(shí)間片中斷OsTimeTick(),用戶(hù)使用的中斷)。
調度算法書(shū)上講得很清楚，我主要講一下整體思路。
(1)在調用API函數時(shí)，有可能引起阻塞,如果系統API函數察覺(jué)到運行條件不滿(mǎn)足，需要切換就調用OSSched()調度函數，這個(gè)過(guò)程是系統自動(dòng)完成的，用戶(hù)沒(méi)有參與。OSSched()判斷是否切換，如果需要切換，則此函數調用OS_TASK_SW()。這個(gè)函數模擬一次中斷(在51里沒(méi)有軟中斷，我用子程序調用模擬，效果相同)，好象程序被中斷打斷了，其實(shí)是OS故意制造的假象，目的是為了任務(wù)切換。既然是中斷，那么返回地址(即緊鄰OS_TASK_SW()的下一條匯編指令的PC地址)就被自動(dòng)壓入堆棧，接著(zhù)在中斷程序里保存CPU寄存器(PUSHALL)……。堆棧結構不是任意的，而是嚴格按照uCOSII規范處理。OS每次切換都會(huì )保存和恢復全部現場(chǎng)信息(POPALL)，然后用RETI回到任務(wù)斷點(diǎn)繼續執行。這個(gè)斷點(diǎn)就是OSSched()函數里的緊鄰OS_TASK_SW()的下一條匯編指令的PC地址。切換的整個(gè)過(guò)程就是，用戶(hù)任務(wù)程序調用系統API函數，API調用OSSched()，OSSched()調用軟中斷OS_TASK_SW()即OSCtxSw，返回地址(PC值)壓棧，進(jìn)入OSCtxSw中斷處理子程序內部。反之，切換程序調用RETI返回緊鄰OS_TASK_SW()的下一條匯編指令的PC地址，進(jìn)而返回OSSched()下一句，再返回API下一句，即用戶(hù)程序斷點(diǎn)。因此，如果任務(wù)從運行到就緒再到運行，它是從調度前的斷點(diǎn)處運行。
(2)中斷會(huì )引發(fā)條件變化，在退出前必須進(jìn)行任務(wù)調度。uCOSII要求中斷的堆棧結構符合規范，以便正確協(xié)調中斷退出和任務(wù)切換。前面已經(jīng)說(shuō)到任務(wù)切換實(shí)際是模擬一次中斷事件，而在真正的中斷里省去了模擬(本身就是中斷嘛)。只要規定中斷堆棧結構和uCOSII模擬的堆棧結構一樣，就能保證在中斷里進(jìn)行正確的切換。任務(wù)切換發(fā)生在中斷退出前，此時(shí)還沒(méi)有返回中斷斷點(diǎn)。仔細觀(guān)察中斷程序和切換程序最后兩句，它們是一模一樣的，POPALL+RETI。即要么直接從中斷程序退出，返回斷點(diǎn)；要么先保存現場(chǎng)到TCB，等到恢復現場(chǎng)時(shí)再從切換函數返回原來(lái)的中斷斷點(diǎn)(由于中斷和切換函數遵循共同的堆棧結構，所以退出操作相同，效果也相同)。用戶(hù)編寫(xiě)的中斷子程序必須按照uCOSII規范書(shū)寫(xiě)。任務(wù)調度發(fā)生在中斷退出前，是非常及時(shí)的，不會(huì )等到下一時(shí)間片才處理。OSIntCtxSw()函數對堆棧指針做了簡(jiǎn)單調整，以保證所有掛起任務(wù)的棧結構看起來(lái)是一樣的。
(3)在uCOSII里，任務(wù)必須寫(xiě)成兩種形式之一(《uCOSII中文版》p99頁(yè))。在有些RTOS開(kāi)發(fā)環(huán)境里沒(méi)有要求顯式調用OSTaskDel()，這是因為開(kāi)發(fā)環(huán)境自動(dòng)做了處理，實(shí)際原理都是一樣的。uCOSII的開(kāi)發(fā)依賴(lài)于編譯器，目前沒(méi)有專(zhuān)用開(kāi)發(fā)環(huán)境，所以出現這些不便之處是可以理解的。
移植過(guò)程：
(1)拷貝書(shū)后附贈光盤(pán)sourcecode目錄下的內容到C:YY下，刪除不必要的文件和EX1L.C，只剩下p187(《uCOSII》)上列出的文件。
(2)改寫(xiě)最簡(jiǎn)單的OS_CPU.H
數據類(lèi)型的設定見(jiàn)C51.PDF第176頁(yè)。注意BOOLEAN要定義成unsigned char 類(lèi)型，因為bit類(lèi)型為C51特有，不能用在結構體里。
EA=0關(guān)中斷；EA=1開(kāi)中斷。這樣定義即減少了程序行數，又避免了退出臨界區后關(guān)中斷造成的死機。
MCS-51堆棧從下往上增長(cháng)(1=向下，0=向上)，OS_STK_GROWTH定義為0
#define OS_TASK_SW() OSCtxSw() 因為MCS-51沒(méi)有軟中斷指令，所以用程序調用代替。兩者的堆棧格式相同，RETI指令復位中斷系統，RET則沒(méi)有。實(shí)踐表明，對于MCS-51，用子程序調用入棧，用中斷返回指令RETI出棧是沒(méi)有問(wèn)題的，反之中斷入棧RET出棧則不行?？傊?，對于入棧，子程序調用與中斷調用效果是一樣的，可以混用。在沒(méi)有中斷發(fā)生的情況下復位中斷系統也不會(huì )影響系統正常運行。詳見(jiàn)《uC/OS-II》第八章193頁(yè)第12行
(3)改寫(xiě)OS_CPU_C.C
我設計的堆棧結構如下圖所示：

TCB結構體中OSTCBStkPtr總是指向用戶(hù)堆棧最低地址，該地址空間內存放用戶(hù)堆棧長(cháng)度，其上空間存放系統堆棧映像，即：用戶(hù)堆?？臻g大小=系統堆?？臻g大小+1。
SP總是先加1再存數據，因此，SP初始時(shí)指向系統堆棧起始地址(OSStack)減1處(OSStkStart)。很明顯系統堆棧存儲空間大小=SP-OSStkStart。
任務(wù)切換時(shí)，先保存當前任務(wù)堆棧內容。方法是：用SP-OSStkStart得出保存字節數，將其寫(xiě)入用戶(hù)堆棧最低地址內，以用戶(hù)堆棧最低地址為起址，以OSStkStart為系統堆棧起址，由系統棧向用戶(hù)?？截悢祿?，循環(huán)SP-OSStkStart次，每次拷貝前先將各自棧指針增1。
其次，恢復最高優(yōu)先級任務(wù)系統堆棧。方法是：獲得最高優(yōu)先級任務(wù)用戶(hù)堆棧最低地址，從中取出“長(cháng)度”，以最高優(yōu)先級任務(wù)用戶(hù)堆棧最低地址為起址，以OSStkStart為系統堆棧起址，由用戶(hù)棧向系統?？截悢祿?，循環(huán)“長(cháng)度”數值指示的次數，每次拷貝前先將各自棧指針增1。
用戶(hù)堆棧初始化時(shí)從下向上依次保存：用戶(hù)堆棧長(cháng)度（15），PCL，PCH，PSW，ACC，B，DPL，DPH，R0，R1，R2，R3，R4，R5，R6，R7。不保存SP，任務(wù)切換時(shí)根據用戶(hù)堆棧長(cháng)度計算得出。
OSTaskStkInit函數總是返回用戶(hù)棧最低地址。
操作系統tick時(shí)鐘我使用了51單片機的T0定時(shí)器，它的初始化代碼用C寫(xiě)在了本文件中。
最后還有幾點(diǎn)必須注意的事項。本來(lái)原則上我們不用修改與處理器無(wú)關(guān)的代碼，但是由于KEIL編譯器的特殊性，這些代碼仍要多處改動(dòng)。因為KEIL缺省情況下編譯的代碼不可重入，而多任務(wù)系統要求并發(fā)操作導致重入，所以要在每個(gè)C函數及其聲明后標注reentrant關(guān)鍵字。另外，“pdata”、“data”在uCOS中用做一些函數的形參，但它同時(shí)又是KEIL的關(guān)鍵字，會(huì )導致編譯錯誤，我通過(guò)把“pdata”改成“ppdata”，“data”改成“ddata”解決了此問(wèn)題。OSTCBCur、OSTCBHighRdy、OSRunning、OSPrioCur、OSPrioHighRdy這幾個(gè)變量在匯編程序中用到了，為了使用Ri訪(fǎng)問(wèn)而不用DPTR，應該用KEIL擴展關(guān)鍵字IDATA將它們定義在內部RAM中。
(4)重寫(xiě)OS_CPU_A.ASM
A51宏匯編的大致結構如下：
NAME 模塊名 ;與文件名無(wú)關(guān)
定義重定位段 必須按照C51格式定義，匯編遵守C51規范。段名格式為：?PR?函數名?模塊名
聲明引用全局變量和外部子程序 注意關(guān)鍵字為“EXTRN”沒(méi)有‘E’
全局變量名直接引用
無(wú)參數/無(wú)寄存器參數函數 FUNC
帶寄存器參數函數 _FUNC
重入函數 _?FUNC
分配堆?？臻g
只關(guān)心大小，堆棧起點(diǎn)由keil決定，通過(guò)標號可以獲得keil分配的SP起點(diǎn)。切莫自己分配堆棧起點(diǎn)，只要用DS通知KEIL預留堆?？臻g即可。
?STACK段名與STARTUP.A51中的段名相同，這意味著(zhù)KEIL在LINK時(shí)將把兩個(gè)同名段拼在一起，我預留了40H個(gè)字節，STARTUP.A51預留了1個(gè)字節，LINK完成后堆棧段總長(cháng)為41H。查看yy.m51知KEIL將堆棧起點(diǎn)定在21H，長(cháng)度41H，處于內部RAM中。
定義宏
宏名 MACRO 實(shí)體 ENDM
子程序
OSStartHighRdy
OSCtxSw
OSIntCtxSw
OSTickISR
SerialISR
END ;聲明匯編源文件結束

一般指針占3字節。+0類(lèi)型+1高8位數據+2低8位數據 詳見(jiàn)C51.PDF第178頁(yè)
低位地址存高8位值，高位地址存低8位值。例如0x1234，基址+0:0x12 基址+1:0x34

(5)移植串口驅動(dòng)程序
在此之前我寫(xiě)過(guò)基于中斷的串口驅動(dòng)程序，包括打印字節/字/長(cháng)字/字符串，讀串口，初始化串口/緩沖區。把它改成重入函數即可直接使用。
系統提供的顯示函數是并發(fā)的，它不是直接顯示到串口，而是先輸出到顯存，用戶(hù)不必擔心IO慢速操作影響程序運行。串口輸入也采用了同樣的技術(shù)，他使得用戶(hù)在CPU忙于處理其他任務(wù)時(shí)照樣可以盲打輸入命令。
(6)編寫(xiě)測試程序Demo(YY.C)
Demo程序創(chuàng )建了3個(gè)任務(wù)A、B、C優(yōu)先級分別為2、3、4，A每秒顯示一次，B每3秒顯示一次，C每6秒顯示一次。從顯示結果看，顯示3個(gè)A后顯示1個(gè)B，顯示6個(gè)A和2個(gè)B后顯示1個(gè)C，結果顯然正確。
顯示結果如下：
AAAAAA111111 is active
AAAAAA111111 is active
AAAAAA111111 is active
BBBBBB333333 is active
AAAAAA111111 is active
AAAAAA111111 is active
AAAAAA111111 is active
BBBBBB333333 is active
CCCCCC666666 is active
AAAAAA111111 is active
AAAAAA111111 is active
AAAAAA111111 is active
BBBBBB333333 is active
AAAAAA111111 is active
AAAAAA111111 is active
AAAAAA111111 is active
BBBBBB333333 is active
CCCCCC666666 is active
Demo程序經(jīng)Keil701編譯后，代碼量為7-8K，可直接在KeilC51上仿真運行。
編譯時(shí)要將OS_CPU_C.C、UCOS_II.C、OS_CPU_A.ASM、YY.C加入項目

文件名 : OS_CPU_A.ASM

$NOMOD51
EA BIT 0A8H.7
SP DATA 081H
B DATA 0F0H
ACC DATA 0E0H
DPH DATA 083H
DPL DATA 082H
PSW DATA 0D0H
TR0 BIT 088H.4
TH0 DATA 08CH
TL0 DATA 08AH

NAME OS_CPU_A ;模塊名

定義重定位段
?PR?OSStartHighRdy?OS_CPU_A SEGMENT CODE
?PR?OSCtxSw?OS_CPU_A SEGMENT CODE
?PR?OSIntCtxSw?OS_CPU_A SEGMENT CODE
?PR?OSTickISR?OS_CPU_A SEGMENT CODE

?PR?_?serial?OS_CPU_A SEGMENT CODE

聲明引用全局變量和外部子程序
EXTRN IDATA (OSTCBCur)
EXTRN IDATA (OSTCBHighRdy)
EXTRN IDATA (OSRunning)
EXTRN IDATA (OSPrioCur)
EXTRN IDATA (OSPrioHighRdy)

EXTRN CODE (_?OSTaskSwHook)
EXTRN CODE (_?serial)
EXTRN CODE (_?OSIntEnter)
EXTRN CODE (_?OSIntExit)
EXTRN CODE (_?OSTimeTick)

對外聲明4個(gè)不可重入函數
PUBLIC OSStartHighRdy
PUBLIC OSCtxSw
PUBLIC OSIntCtxSw
PUBLIC OSTickISR

PUBLIC SerialISR

分配堆?？臻g。只關(guān)心大小，堆棧起點(diǎn)由keil決定，通過(guò)標號可以獲得keil分配的SP起點(diǎn)。
?STACK SEGMENT IDATA
RSEG ?STACK
OSStack:
DS 40H
OSStkStart IDATA OSStack-1

定義壓棧出棧宏
PUSHALL MACRO
PUSH PSW
PUSH ACC
PUSH B
PUSH DPL
PUSH DPH
MOV A,R0 ;R0-R7入棧
PUSH ACC
MOV A,R1
PUSH ACC
MOV A,R2
PUSH ACC
MOV A,R3
PUSH ACC
MOV A,R4
PUSH ACC
MOV A,R5
PUSH ACC
MOV A,R6
PUSH ACC
MOV A,R7
PUSH ACC
PUSH SP ;不必保存SP，任務(wù)切換時(shí)由相應程序調整
ENDM

POPALL MACRO
POP ACC ;不必保存SP，任務(wù)切換時(shí)由相應程序調整
POP ACC ;R0-R7出棧
MOV R7,A
POP ACC
MOV R6,A
POP ACC
MOV R5,A
POP ACC
MOV R4,A
POP ACC
MOV R3,A
POP ACC
MOV R2,A
POP ACC
MOV R1,A
POP ACC
MOV R0,A
POP DPH
POP DPL
POP B
POP ACC
POP PSW
ENDM

子程序
-------------------------------------------------------------------------
RSEG ?PR?OSStartHighRdy?OS_CPU_A
OSStartHighRdy:
USING 0 ;上電后51自動(dòng)關(guān)中斷，此處不必用CLR EA指令，因為到此處還未開(kāi)中斷，本程序退出后，開(kāi)中斷。
LCALL _?OSTaskSwHook

OSCtxSw_in:

OSTCBCur ===> DPTR 獲得當前TCB指針，詳見(jiàn)C51.PDF第178頁(yè)
MOV R0,#LOW (OSTCBCur) ;獲得OSTCBCur指針低地址，指針占3字節。+0類(lèi)型+1高8位數據+2低8位數據
INC R0
MOV DPH,@R0 ;全局變量OSTCBCur在IDATA中
INC R0
MOV DPL,@R0

OSTCBCur->OSTCBStkPtr ===> DPTR 獲得用戶(hù)堆棧指針
INC DPTR ;指針占3字節。+0類(lèi)型+1高8位數據+2低8位數據
MOVX A,@DPTR ;.OSTCBStkPtr是void指針
MOV R0,A
INC DPTR
MOVX A,@DPTR
MOV R1,A
MOV DPH,R0
MOV DPL,R1

*UserStkPtr ===> R5 用戶(hù)堆棧起始地址內容(即用戶(hù)堆棧長(cháng)度放在此處) 詳見(jiàn)文檔說(shuō)明 指針用法詳見(jiàn)C51.PDF第178頁(yè)
MOVX A,@DPTR ;用戶(hù)堆棧中是unsigned char類(lèi)型數據
MOV R5,A ;R5=用戶(hù)堆棧長(cháng)度

恢復現場(chǎng)堆棧內容
MOV R0,#OSStkStart

restore_stack:

INC DPTR
INC R0
MOVX A,@DPTR
MOV @R0,A
DJNZ R5,restore_stack

恢復堆棧指針SP
MOV SP,R0

OSRunning=TRUE
MOV R0,#LOW (OSRunning)
MOV @R0,#01

POPALL
SETB EA ;開(kāi)中斷
RETI
-------------------------------------------------------------------------
RSEG ?PR?OSCtxSw?OS_CPU_A
OSCtxSw:
PUSHALL

OSIntCtxSw_in:

獲得堆棧長(cháng)度和起址
MOV A,SP
CLR C
SUBB A,#OSStkStart
MOV R5,A ;獲得堆棧長(cháng)度

OSTCBCur ===> DPTR 獲得當前TCB指針，詳見(jiàn)C51.PDF第178頁(yè)
MOV R0,#LOW (OSTCBCur) ;獲得OSTCBCur指針低地址，指針占3字節。+0類(lèi)型+1高8位數據+2低8位數據
INC R0
MOV DPH,@R0 ;全局變量OSTCBCur在IDATA中
INC R0
MOV DPL,@R0

OSTCBCur->OSTCBStkPtr ===> DPTR 獲得用戶(hù)堆棧指針
INC DPTR ;指針占3字節。+0類(lèi)型+1高8位數據+2低8位數據
MOVX A,@DPTR ;.OSTCBStkPtr是void指針
MOV R0,A
INC DPTR
MOVX A,@DPTR
MOV R1,A
MOV DPH,R0
MOV DPL,R1

保存堆棧長(cháng)度
MOV A,R5
MOVX @DPTR,A

MOV R0,#OSStkStart ;獲得堆棧起址
save_stack:

INC DPTR
INC R0
MOV A,@R0
MOVX @DPTR,A
DJNZ R5,save_stack

調用用戶(hù)程序
LCALL _?OSTaskSwHook

OSTCBCur = OSTCBHighRdy
MOV R0,#OSTCBCur
MOV R1,#OSTCBHighRdy
MOV A,@R1
MOV @R0,A
INC R0
INC R1
MOV A,@R1
MOV @R0,A
INC R0
INC R1
MOV A,@R1
MOV @R0,A

OSPrioCur = OSPrioHighRdy 使用這兩個(gè)變量主要目的是為了使指針比較變?yōu)樽止澅容^，以便節省時(shí)間。
MOV R0,#OSPrioCur
MOV R1,#OSPrioHighRdy
MOV A,@R1
MOV @R0,A

LJMP OSCtxSw_in
-------------------------------------------------------------------------
RSEG ?PR?OSIntCtxSw?OS_CPU_A

OSIntCtxSw:

調整SP指針去掉在調用OSIntExit(),OSIntCtxSw()過(guò)程中壓入堆棧的多余內容
SP=SP-4

MOV A,SP
CLR C
SUBB A,#4
MOV SP,A

LJMP OSIntCtxSw_in
-------------------------------------------------------------------------
CSEG AT 000BH ;OSTickISR
LJMP OSTickISR ;使用定時(shí)器0
RSEG ?PR?OSTickISR?OS_CPU_A

OSTickISR:

USING 0
PUSHALL

CLR TR0
MOV TH0,#70H ;定義Tick=50次/秒(即0.02秒/次)
MOV TL0,#00H ;OS_CPU_C.C 和 OS_TICKS_PER_SEC
SETB TR0

LCALL _?OSIntEnter
LCALL _?OSTimeTick
LCALL _?OSIntExit
POPALL
RETI
-------------------------------------------------------------------------
CSEG AT 0023H ;串口中斷
LJMP SerialISR ;工作于系統態(tài)，無(wú)任務(wù)切換。
RSEG ?PR?_?serial?OS_CPU_A

SerialISR:

USING 0
PUSHALL
CLR EA
LCALL _?serial
SETB EA
POPALL
RETI
-------------------------------------------------------------------------
END
-------------------------------------------------------------------------

文件名 : OS_CPU_C.C

void *OSTaskStkInit (void (*task)(void *pd), void *ppdata, void *ptos, INT16U opt) reentrant
{
OS_STK *stk;

ppdata = ppdata;
opt = opt; //opt沒(méi)被用到，保留此語(yǔ)句防止告警產(chǎn)生
stk = (OS_STK *)ptos; //用戶(hù)堆棧最低有效地址
*stk++ = 15; //用戶(hù)堆棧長(cháng)度
*stk++ = (INT16U)task & 0xFF; //任務(wù)地址低8位
*stk++ = (INT16U)task >> 8; //任務(wù)地址高8位
*stk++ = 0x00; //PSW
*stk++ = 0x0A; //ACC
*stk++ = 0x0B; //B
*stk++ = 0x00; //DPL
*stk++ = 0x00; //DPH
*stk++ = 0x00; //R0
*stk++ = 0x01; //R1
*stk++ = 0x02; //R2
*stk++ = 0x03; //R3
*stk++ = 0x04; //R4
*stk++ = 0x05; //R5
*stk++ = 0x06; //R6
*stk++ = 0x07; //R7
//不用保存SP，任務(wù)切換時(shí)根據用戶(hù)堆棧長(cháng)度計算得出。
return ((void *)ptos);
}

#if OS_CPU_HOOKS_EN
void OSTaskCreateHook (OS_TCB *ptcb) reentrant
{
ptcb = ptcb;
}

void OSTaskDelHook (OS_TCB *ptcb) reentrant
{
ptcb = ptcb;
}

void OSTimeTickHook (void) reentrant
{
}
#endif

//初始化定時(shí)器0
void InitTimer0(void) reentrant
{
TMOD=TMOD&0xF0;
TMOD=TMOD|0x01; //模式1(16位定時(shí)器)，僅受TR0控制
TH0=0x70; //定義Tick=50次/秒(即0.02秒/次)
TL0=0x00; //OS_CPU_A.ASM 和 OS_TICKS_PER_SEC
ET0=1; //允許T0中斷
TR0=1;
}