在51系列單片機上移植uCOS-II

uC/OS-II原理：
uCOSII包括任務(wù)調度、時(shí)間管理、內存管理、資源管理（信號量、郵箱、消息隊列）四大部分，沒(méi)有文件系統、網(wǎng)絡(luò )接口、輸入輸出界面。它的移植只與4個(gè)文件相關(guān)：匯編文件（OS_CPU_A.ASM）、處理器相關(guān)C文件（OS_CPU.H、OS_CPU_C.C）和配置文件（OS_CFG.H）。有64個(gè)優(yōu)先級，系統占用8個(gè)，用戶(hù)可創(chuàng )建56個(gè)任務(wù)，不支持時(shí)間片輪轉。它的基本思路就是 “近似地每時(shí)每刻總是讓優(yōu)先級最高的就緒任務(wù)處于運行狀態(tài)” 。為了保證這一點(diǎn)，它在調用系統API函數、中斷結束、定時(shí)中斷結束時(shí)總是執行調度算法。原作者通過(guò)事先計算好數據，簡(jiǎn)化了運算量，通過(guò)精心設計就緒表結構，使得延時(shí)可預知。任務(wù)的切換是通過(guò)模擬一次中斷實(shí)現的。
uCOSII工作核心原理是：近似地讓最高優(yōu)先級的就緒任務(wù)處于運行狀態(tài)。
操作系統將在下面情況中進(jìn)行任務(wù)調度：調用API函數(用戶(hù)主動(dòng)調用)，中斷(系統占用的時(shí)間片中斷OsTimeTick(),用戶(hù)使用的中斷)。
調度算法書(shū)上講得很清楚，我主要講一下整體思路。
(1)在調用API函數時(shí)，有可能引起阻塞,如果系統API函數察覺(jué)到運行條件不滿(mǎn)足，需要切換就調用OSSched()調度函數，這個(gè)過(guò)程是系統自動(dòng)完成的，用戶(hù)沒(méi)有參與。OSSched()判斷是否切換，如果需要切換，則此函數調用OS_TASK_SW()。這個(gè)函數模擬一次中斷(在51里沒(méi)有軟中斷，我用子程序調用模擬，效果相同)，好象程序被中斷打斷了，其實(shí)是OS故意制造的假象，目的是為了任務(wù)切換。既然是中斷，那么返回地址(即緊鄰OS_TASK_SW()的下一條匯編指令的PC地址)就被自動(dòng)壓入堆棧，接著(zhù)在中斷程序里保存CPU寄存器(PUSHALL)……。堆棧結構不是任意的，而是嚴格按照uCOSII規范處理。OS每次切換都會(huì )保存和恢復全部現場(chǎng)信息(POPALL)，然后用RETI回到任務(wù)斷點(diǎn)繼續執行。這個(gè)斷點(diǎn)就是OSSched()函數里的緊鄰OS_TASK_SW()的下一條匯編指令的PC地址。切換的整個(gè)過(guò)程就是，用戶(hù)任務(wù)程序調用系統API函數，API調用OSSched()，OSSched()調用軟中斷OS_TASK_SW()即OSCtxSw，返回地址(PC值)壓棧，進(jìn)入OSCtxSw中斷處理子程序內部。反之，切換程序調用RETI返回緊鄰OS_TASK_SW()的下一條匯編指令的PC地址，進(jìn)而返回OSSched()下一句，再返回API下一句，即用戶(hù)程序斷點(diǎn)。因此，如果任務(wù)從運行到就緒再到運行，它是從調度前的斷點(diǎn)處運行。
(2)中斷會(huì )引發(fā)條件變化，在退出前必須進(jìn)行任務(wù)調度。uCOSII要求中斷的堆棧結構符合規范，以便正確協(xié)調中斷退出和任務(wù)切換。前面已經(jīng)說(shuō)到任務(wù)切換實(shí)際是模擬一次中斷事件，而在真正的中斷里省去了模擬(本身就是中斷嘛)。只要規定中斷堆棧結構和uCOSII模擬的堆棧結構一樣，就能保證在中斷里進(jìn)行正確的切換。任務(wù)切換發(fā)生在中斷退出前，此時(shí)還沒(méi)有返回中斷斷點(diǎn)。仔細觀(guān)察中斷程序和切換程序最后兩句，它們是一模一樣的，POPALL+RETI。即要么直接從中斷程序退出，返回斷點(diǎn)；要么先保存現場(chǎng)到TCB，等到恢復現場(chǎng)時(shí)再從切換函數返回原來(lái)的中斷斷點(diǎn)(由于中斷和切換函數遵循共同的堆棧結構，所以退出操作相同，效果也相同)。用戶(hù)編寫(xiě)的中斷子程序必須按照uCOSII規范書(shū)寫(xiě)。任務(wù)調度發(fā)生在中斷退出前，是非常及時(shí)的，不會(huì )等到下一時(shí)間片才處理。OSIntCtxSw()函數對堆棧指針做了簡(jiǎn)單調整，以保證所有掛起任務(wù)的棧結構看起來(lái)是一樣的。
(3)在uCOSII里，任務(wù)必須寫(xiě)成兩種形式之一(《uCOSII中文版》p99頁(yè))。在有些RTOS開(kāi)發(fā)環(huán)境里沒(méi)有要求顯式調用OSTaskDel()，這是因為開(kāi)發(fā)環(huán)境自動(dòng)做了處理，實(shí)際原理都是一樣的。uCOSII的開(kāi)發(fā)依賴(lài)于編譯器，目前沒(méi)有專(zhuān)用開(kāi)發(fā)環(huán)境，所以出現這些不便之處是可以理解的。
移植過(guò)程：
(1)拷貝書(shū)后附贈光盤(pán)sourcecode目錄下的內容到C:YY下，刪除不必要的文件和EX1L.C，只剩下p187(《uCOSII》)上列出的文件。
(2)改寫(xiě)最簡(jiǎn)單的OS_CPU.H
數據類(lèi)型的設定見(jiàn)C51.PDF第176頁(yè)。注意BOOLEAN要定義成unsigned char 類(lèi)型，因為bit類(lèi)型為C51特有，不能用在結構體里。
EA=0關(guān)中斷；EA=1開(kāi)中斷。這樣定義即減少了程序行數，又避免了退出臨界區后關(guān)中斷造成的死機。
MCS-51堆棧從下往上增長(cháng)(1=向下，0=向上)，OS_STK_GROWTH定義為0
#define OS_TASK_SW() OSCtxSw() 因為MCS-51沒(méi)有軟中斷指令，所以用程序調用代替。兩者的堆棧格式相同，RETI指令復位中斷系統，RET則沒(méi)有。實(shí)踐表明，對于MCS-51，用子程序調用入棧，用中斷返回指令RETI出棧是沒(méi)有問(wèn)題的，反之中斷入棧RET出棧則不行?？傊?，對于入棧，子程序調用與中斷調用效果是一樣的，可以混用。在沒(méi)有中斷發(fā)生的情況下復位中斷系統也不會(huì )影響系統正常運行。詳見(jiàn)《uC/OS-II》第八章193頁(yè)第12行
(3)改寫(xiě)OS_CPU_C.C
我設計的堆棧結構如下圖所示：

文件名 : OS_CPU_A.ASM

$NOMOD51
EA BIT 0A8H.7
SP DATA 081H
B DATA 0F0H
ACC DATA 0E0H
DPH DATA 083H
DPL DATA 082H
PSW DATA 0D0H
TR0 BIT 088H.4
TH0 DATA 08CH
TL0 DATA 08AH

NAME OS_CPU_A ;模塊名

;定義重定位段
?PR?OSStartHighRdy?OS_CPU_A SEGMENT CODE
?PR?OSCtxSw?OS_CPU_A SEGMENT CODE
?PR?OSIntCtxSw?OS_CPU_A SEGMENT CODE
?PR?OSTickISR?OS_CPU_A SEGMENT CODE

?PR?_?serial?OS_CPU_A SEGMENT CODE

;聲明引用全局變量和外部子程序
EXTRN IDATA (OSTCBCur)
EXTRN IDATA (OSTCBHighRdy)
EXTRN IDATA (OSRunning)
EXTRN IDATA (OSPrioCur)
EXTRN IDATA (OSPrioHighRdy)

EXTRN CODE (_?OSTaskSwHook)
EXTRN CODE (_?serial)
EXTRN CODE (_?OSIntEnter)
EXTRN CODE (_?OSIntExit)
EXTRN CODE (_?OSTimeTick)

;對外聲明4個(gè)不可重入函數
PUBLIC OSStartHighRdy
PUBLIC OSCtxSw
PUBLIC OSIntCtxSw
PUBLIC OSTickISR

;PUBLIC SerialISR

;分配堆?？臻g。只關(guān)心大小，堆棧起點(diǎn)由keil決定，通過(guò)標號可以獲得keil分配的SP起點(diǎn)。
?STACK SEGMENT IDATA
RSEG ?STACK
OSStack:
DS 40H
OSStkStart IDATA OSStack-1

;定義壓棧出棧宏
PUSHALL MACRO
PUSH PSW
PUSH ACC
PUSH B
PUSH DPL
PUSH DPH
MOV A,R0 ;R0-R7入棧
PUSH ACC
MOV A,R1
PUSH ACC
MOV A,R2
PUSH ACC
MOV A,R3
PUSH ACC
MOV A,R4
PUSH ACC
MOV A,R5
PUSH ACC
MOV A,R6
PUSH ACC
MOV A,R7
PUSH ACC
;PUSH SP ;不必保存SP，任務(wù)切換時(shí)由相應程序調整
ENDM

POPALL MACRO
;POP ACC ;不必保存SP，任務(wù)切換時(shí)由相應程序調整
POP ACC ;R0-R7出棧
MOV R7,A
POP ACC
MOV R6,A
POP ACC
MOV R5,A
POP ACC
MOV R4,A
POP ACC
MOV R3,A
POP ACC
MOV R2,A
POP ACC
MOV R1,A
POP ACC
MOV R0,A
POP DPH
POP DPL
POP B
POP ACC
POP PSW
ENDM

;子程序
;-------------------------------------------------------------------------
RSEG ?PR?OSStartHighRdy?OS_CPU_A
OSStartHighRdy:
USING 0 ;上電后51自動(dòng)關(guān)中斷，此處不必用CLR EA指令，因為到此處還未開(kāi)中斷，本程序退出后，開(kāi)中斷。
LCALL _?OSTaskSwHook

OSCtxSw_in:

;OSTCBCur ===> DPTR 獲得當前TCB指針，詳見(jiàn)C51.PDF第178頁(yè)
MOV R0,#LOW (OSTCBCur) ;獲得OSTCBCur指針低地址，指針占3字節。+0類(lèi)型+1高8位數據+2低8位數據
INC R0
MOV DPH,@R0 ;全局變量OSTCBCur在IDATA中
INC R0
MOV DPL,@R0

;OSTCBCur->OSTCBStkPtr ===> DPTR 獲得用戶(hù)堆棧指針
INC DPTR ;指針占3字節。+0類(lèi)型+1高8位數據+2低8位數據
MOVX A,@DPTR ;.OSTCBStkPtr是void指針
MOV R0,A
INC DPTR
MOVX A,@DPTR
MOV R1,A
MOV DPH,R0
MOV DPL,R1

;*UserStkPtr ===> R5 用戶(hù)堆棧起始地址內容(即用戶(hù)堆棧長(cháng)度放在此處) 詳見(jiàn)文檔說(shuō)明 指針用法詳見(jiàn)C51.PDF第178頁(yè)
MOVX A,@DPTR ;用戶(hù)堆棧中是unsigned char類(lèi)型數據
MOV R5,A ;R5=用戶(hù)堆棧長(cháng)度

;恢復現場(chǎng)堆棧內容
MOV R0,#OSStkStart

restore_stack:

INC DPTR
INC R0
MOVX A,@DPTR
MOV @R0,A
DJNZ R5,restore_stack

;恢復堆棧指針SP
MOV SP,R0

;OSRunning=TRUE
MOV R0,#LOW (OSRunning)
MOV @R0,#01

POPALL
SETB EA ;開(kāi)中斷
RETI
;-------------------------------------------------------------------------
RSEG ?PR?OSCtxSw?OS_CPU_A
OSCtxSw:
PUSHALL

OSIntCtxSw_in:

;獲得堆棧長(cháng)度和起址
MOV A,SP
CLR C
SUBB A,#OSStkStart
MOV R5,A ;獲得堆棧長(cháng)度

;OSTCBCur ===> DPTR 獲得當前TCB指針，詳見(jiàn)C51.PDF第178頁(yè)
MOV R0,#LOW (OSTCBCur) ;獲得OSTCBCur指針低地址，指針占3字節。+0類(lèi)型+1高8位數據+2低8位數據
INC R0
MOV DPH,@R0 ;全局變量OSTCBCur在IDATA中
INC R0
MOV DPL,@R0

;OSTCBCur->OSTCBStkPtr ===> DPTR 獲得用戶(hù)堆棧指針
INC DPTR ;指針占3字節。+0類(lèi)型+1高8位數據+2低8位數據
MOVX A,@DPTR ;.OSTCBStkPtr是void指針
MOV R0,A
INC DPTR
MOVX A,@DPTR
MOV R1,A
MOV DPH,R0
MOV DPL,R1

;保存堆棧長(cháng)度
MOV A,R5
MOVX @DPTR,A

MOV R0,#OSStkStart ;獲得堆棧起址
save_stack:

INC DPTR
INC R0
MOV A,@R0
MOVX @DPTR,A
DJNZ R5,save_stack

;調用用戶(hù)程序
LCALL _?OSTaskSwHook

;OSTCBCur = OSTCBHighRdy
MOV R0,#OSTCBCur
MOV R1,#OSTCBHighRdy
MOV A,@R1
MOV @R0,A
INC R0
INC R1
MOV A,@R1
MOV @R0,A
INC R0
INC R1
MOV A,@R1
MOV @R0,A

;OSPrioCur = OSPrioHighRdy 使用這兩個(gè)變量主要目的是為了使指針比較變?yōu)樽止澅容^，以便節省時(shí)間。
MOV R0,#OSPrioCur
MOV R1,#OSPrioHighRdy
MOV A,@R1
MOV @R0,A

LJMP OSCtxSw_in
;-------------------------------------------------------------------------
RSEG ?PR?OSIntCtxSw?OS_CPU_A

OSIntCtxSw:

;調整SP指針去掉在調用OSIntExit(),OSIntCtxSw()過(guò)程中壓入堆棧的多余內容
;SP=SP-4

MOV A,SP
CLR C
SUBB A,#4
MOV SP,A

LJMP OSIntCtxSw_in
;-------------------------------------------------------------------------
CSEG AT 000BH ;OSTickISR
LJMP OSTickISR ;使用定時(shí)器0
RSEG ?PR?OSTickISR?OS_CPU_A

OSTickISR:

USING 0
PUSHALL

CLR TR0
MOV TH0,#70H ;定義Tick=50次/秒(即0.02秒/次)
MOV TL0,#00H ;OS_CPU_C.C 和 OS_TICKS_PER_SEC
SETB TR0

LCALL _?OSIntEnter
LCALL _?OSTimeTick
LCALL _?OSIntExit
POPALL
RETI
;-------------------------------------------------------------------------
CSEG AT 0023H ;串口中斷
LJMP SerialISR ;工作于系統態(tài)，無(wú)任務(wù)切換。
RSEG ?PR?_?serial?OS_CPU_A

SerialISR:

USING 0
PUSHALL
CLR EA
LCALL _?serial
SETB EA
POPALL
RETI
;-------------------------------------------------------------------------
END
;-------------------------------------------------------------------------

文件名 : OS_CPU_C.C

void *OSTaskStkInit (void (*task)(void *pd), void *ppdata, void *ptos, INT16U opt) reentrant
{
OS_STK *stk;

ppdata = ppdata;
opt = opt; //opt沒(méi)被用到，保留此語(yǔ)句防止告警產(chǎn)生
stk = (OS_STK *)ptos; //用戶(hù)堆棧最低有效地址
*stk++ = 15; //用戶(hù)堆棧長(cháng)度
*stk++ = (INT16U)task & 0xFF; //任務(wù)地址低8位
*stk++ = (INT16U)task >> 8; //任務(wù)地址高8位
*stk++ = 0x00; //PSW
*stk++ = 0x0A; //ACC
*stk++ = 0x0B; //B
*stk++ = 0x00; //DPL
*stk++ = 0x00; //DPH
*stk++ = 0x00; //R0
*stk++ = 0x01; //R1
*stk++ = 0x02; //R2
*stk++ = 0x03; //R3
*stk++ = 0x04; //R4
*stk++ = 0x05; //R5
*stk++ = 0x06; //R6
*stk++ = 0x07; //R7
//不用保存SP，任務(wù)切換時(shí)根據用戶(hù)堆棧長(cháng)度計算得出。
return ((void *)ptos);
}

#if OS_CPU_HOOKS_EN
void OSTaskCreateHook (OS_TCB *ptcb) reentrant
{
ptcb = ptcb; /* Prevent compiler warning */
}

void OSTaskDelHook (OS_TCB *ptcb) reentrant
{
ptcb = ptcb; /* Prevent compiler warning */
}

void OSTimeTickHook (void) reentrant
{
}
#endif

//初始化定時(shí)器0
void InitTimer0(void) reentrant
{
TMOD=TMOD&0xF0;
TMOD=TMOD|0x01; //模式1(16位定時(shí)器)，僅受TR0控制
TH0=0x70; //定義Tick=50次/秒(即0.02秒/次)
TL0=0x00; //OS_CPU_A.ASM 和 OS_TICKS_PER_SEC
ET0=1; //允許T0中斷
TR0=1;
}

文件名 : YY.C

#include

#define MAX_STK_SIZE 64

void TaskStartyya(void *yydata) reentrant;
void TaskStartyyb(void *yydata) reentrant;
void TaskStartyyc(void *yydata) reentrant;

OS_STK TaskStartStkyya[MAX_STK_SIZE+1];//注意：我在A(yíng)SM文件中設置?STACK空間為40H即64，不要超出范圍。
OS_STK TaskStartStkyyb[MAX_STK_SIZE+1];//用戶(hù)棧多一個(gè)字節存長(cháng)度
OS_STK TaskStartStkyyc[MAX_STK_SIZE+1];

void main(void)
{
OSInit();

InitTimer0();
InitSerial();
InitSerialBuffer();

OSTaskCreate(TaskStartyya, (void *)0, &TaskStartStkyya[0],2);
OSTaskCreate(TaskStartyyb, (void *)0, &TaskStartStkyyb[0],3);
OSTaskCreate(TaskStartyyc, (void *)0, &TaskStartStkyyc[0],4);

OSStart();
}

void TaskStartyya(void *yydata) reentrant
{
yydata=yydata;
clrscr();
PrintStr("ntt*******************************n");
PrintStr("tt* Hello! The world. *n");
PrintStr("tt*******************************nnn");

for(;;){
PrintStr("tAAAAAA111111 is active.n");
OSTimeDly(OS_TICKS_PER_SEC);
}
}

void TaskStartyyb(void *yydata) reentrant
{
yydata=yydata;

for(;;){
PrintStr("tBBBBBB333333 is active.n");
OSTimeDly(3*OS_TICKS_PER_SEC);
}
}

void TaskStartyyc(void *yydata) reentrant
{
yydata=yydata;

for(;;){
PrintStr("tCCCCCC666666 is active.n");
OSTimeDly(6*OS_TICKS_PER_SEC);
}
}

重入問(wèn)題的解決：
任務(wù)函數中帶有形參和局部變量時(shí)若使用reentrant關(guān)鍵字會(huì )引起重入，從C51.PDF 129-131頁(yè)的內容知：為了函數重入，形參和局部變量必須保存在堆棧里，由于51硬件堆棧太小，KEIL將根據內存模式在相應內存空間仿真堆棧(生長(cháng)方向由上向下，與硬件棧相反)。對于大模式編譯，函數返回地址保存在硬件堆棧里，形參和局部變量放在仿真堆棧中，棧指針為?C_XBP，XBPSTACK=1時(shí)，起始值在startup.a51中初始化為FFFFH+1。仿真堆棧效率低下，KEIL建議盡量不用，但為了重入操作必須使用。KEIL可以混合使用3種仿真堆棧(大、中、小模式)，為了提高效率，針對51推薦統一使用大模式編譯。
為了支持重入，重新設計了堆棧結構(如下圖)。增加了保存仿真堆棧指針?C_XBP和堆棧內容的數據結構。相應改變的文件有：OS_CPU_A.ASM、OS_CPU_C.C、OS_CPU.H、YY.C。由圖可知，用戶(hù)棧中保存的仿真棧與硬件棧相向生長(cháng)，中間為空閑間隔，顯然uCOSII的堆棧檢測函數失效。硬件棧的保存恢復詳見(jiàn)上節，仿真堆棧的保存與8086移植中的一樣，OS只提供堆?？臻g和只操作堆棧指針，不進(jìn)行內存拷貝，效率相對很高。
建議使用統一的固定大小的堆?？臻g，盡管uCOSII原作者把不同任務(wù)使用不同空間看成是優(yōu)點(diǎn)，但為了在51上有效實(shí)現任務(wù)重入，針對51筆者還是堅持不使用這個(gè)優(yōu)點(diǎn)。
用戶(hù)堆?？臻g的大小是可以精確計算出來(lái)的。用戶(hù)堆?？臻g=硬件堆?？臻g+仿真堆?？臻g。硬件棧占用內部RAM，內部RAM執行效率高，如果堆?？臻g過(guò)大，會(huì )影響KEIL編譯的程序性能。如果堆?？臻g小，在中斷嵌套和程序調用時(shí)會(huì )造成系統崩潰。綜合考慮，我把硬件堆?？臻g大小定成了64字節，用戶(hù)根據實(shí)際情況可以自行設定。仿真堆棧大小取決于形參和局部變量的類(lèi)型及數量，可以精確算出。因為所有用戶(hù)棧使用相同空間大小，所以取占用空間最大的任務(wù)函數的空間大小為仿真堆?？臻g大小。這樣用戶(hù)堆?？臻g大小就唯一確定了。我將用戶(hù)堆?？臻g大小用宏定義在OS_CFG.H文件中，宏名為MaxStkSize。
51的SP只有8位，無(wú)法在64K空間中自由移動(dòng)，只好采用拷貝全部硬件堆棧內容的笨辦法。51 本來(lái)就弱，這么一來(lái)缺點(diǎn)更明顯了。其實(shí)，引入OS必然要付出代價(jià)，一般OS要占用CPU10%-20%的負荷能力，請權衡利弊決定。切換頻率決定了CPU的耗費，頻率越高耗費越大，大到一定程度就該換更強的CPU了。我選了50Hz的切換頻率，不高也不低，用戶(hù)可以根據需要自行定奪。在耗費無(wú)法避免的情況下，我采取了幾個(gè)措施來(lái)提高效率：1。ret和reti混用減少代碼；2。IE、SP不入出棧，通過(guò)另外方式解決；3。用IDATA關(guān)鍵字聲明在匯編中用到的全局變量，變DPTR操作為Ri操作；4。設計堆棧結構，簡(jiǎn)化算法；5。讓串口輸入輸出工作在系統態(tài)，不占用任務(wù)TCB和優(yōu)先級，增加彈性緩沖區，減少等待。

在51單片機上硬件仿真uCOS51的說(shuō)明：
zyware網(wǎng)友2002/11/22來(lái)信詢(xún)問(wèn)uCOS51在單片機上的硬件仿真問(wèn)題，具體情況是“在51上用uCOS51核，以及一些構件，keilc上仿真通過(guò)，用wave接硬件仿真程序亂飛，wave仿真以前的程序沒(méi)有問(wèn)題，不知是何緣故”。
由于我的OS程序已經(jīng)在KEIL軟件仿真和硬件上實(shí)際測試過(guò)，所以不可能是程序錯?？赡艿脑蛑荒苁怯布抡孳浖O置問(wèn)題。本人用的是Medwin軟件，在Insight上調試，使用uCOS51編譯測試程序一樣跑飛。即使添加修改后的startup.a51(詳見(jiàn)《在51單片機上固化uCOS51的說(shuō)明》)也不正常。我發(fā)現Medwin似乎沒(méi)有編譯startup.a51，因為它把該文件加在了other Files目錄下而不是source Files目錄，于是我猜測只有放在source Files目錄下的文件才被編譯。由觀(guān)察知，以.c和.asm做后綴的文件均被放在此目錄下且被編譯。于是我立即將startup.a51改成startup.asm并加入項目編譯，結果測試正常。不必擔心startup改名造成沖突，KEIL在鏈接目標文件時(shí)會(huì )自動(dòng)處理重名段，本目錄的文件優(yōu)先級高(我是這么理解的，具體原理不清楚，這只是根據實(shí)踐得到的結論，希望了解此處理過(guò)程的朋友能告之，不勝感激。)。

具體做法如下：
1。按《在51單片機上固化uCOS51的說(shuō)明》一文修改startup.a51，并將其更名為startup.asm。
2。將startup.asm、yy1.c、os_cpu_c.c、ucos_ii.c、os_cpu_a.asm五個(gè)文件加入項目編譯。
3。運行

在51單片機上固化uCOS51的說(shuō)明：
近來(lái)，收到多位網(wǎng)友來(lái)信詢(xún)問(wèn)uCOS51在51單片機上的固化問(wèn)題，歸納其焦點(diǎn)就是：為什么OS在KeilC51上模擬可以正常運行，但把它燒錄在CPU上卻不能工作？理論上，程序在軟件仿真通過(guò)測試后，將其燒錄在硬件上，硬件調試應該一次成功。許多網(wǎng)友也有這個(gè)經(jīng)驗，可為什么在調試uCOS51時(shí)失效了呢？難道操作系統調試很特殊嗎？
其實(shí)問(wèn)題出在重入函數的引入。原來(lái)KEILC51軟件仿真在不修改startup.a51文件的情況下，缺剩使用64K外部RAM，它把0000H-FFFFH全部仿真為可讀寫(xiě)的RAM，而用戶(hù)的硬件系統可能沒(méi)有用到那么大的RAM空間，比如只用了8K/16K/32K等，或者用戶(hù)把一些地址空間映射給了別的設備，比如8019AS等。在沒(méi)有調用OSTaskCreate前，定義為reentrant的函數將用FFE0H做仿真堆棧棧頂指針，而此處在用戶(hù)的系統里不是RAM，造成程序跑飛。比如在我的用戶(hù)板上，將FE00H-FFFFH空間的一部分分配給8019AS使用，如果把demo程序編譯后直接燒到51上，將不能運行。解決辦法是根據系統RAM配置，修改startup.a51文件，并將其加入項目編譯，如下所示：

XBPSTACK EQU 1 ; set to 1 if large reentrant is used.
XBPSTACKTOP EQU 07FFFH+1; set top of stack to highest location+1.

按此修改后，在有32K外部RAM的系統上可以正常運行。用戶(hù)可根據自己XRAM的實(shí)際配置情況修改startup.a51相關(guān)參數，并將其添加到項目里編譯。不必理會(huì )KEIL/C51/LIB目錄下的同名文件，此處的startup.a51優(yōu)先級高，KEIL將按此處該文件的配置編譯項目。
這也解釋了有些網(wǎng)友問(wèn)到的，“為什么加入reentrant關(guān)鍵字，在軟件仿真時(shí)正確，燒在芯片上就死機，去掉reentrant后兩者都正?！钡膯?wèn)題。由于大多數人很少使用重入函數，往往不了解這個(gè)細節，特此提請大家注意。

關(guān)于uCOS51不能正常工作的原因還可能是因為串口波特率和OS_TICKS_PER_SEC及TH0、TL0設置不正確引起的。demo程序默認使用22.1184MHz晶體，19200波特率，切換頻率為50Hz。為此，1。在SERIAL.C中設置“TL1=0xFD;TH1=0xFD;”使波特率為19200；2。在OS_CPU_C.C和OS_CPU_A.ASM中設置“TH0=0x70;TL0=0x00;”使時(shí)鐘節拍tick=50次/秒；3。在OS_CFG.H中設置OS_TICKS_PER_SEC為50Hz。用戶(hù)應根據實(shí)際情況，相應地修改這些參數，否則運行不正確。

定時(shí)器初值設置：

定時(shí)器0用于時(shí)鐘節拍發(fā)生器
//*****************************************************************************
//初值計算公式：
// (2^16-x)*F=Fosc/12
// 其中：F=時(shí)鐘節拍頻率tick；Fosc=晶體或晶振頻率；x=初值；
// 本例中，F=50；Fosc=21.1184MHz；所以x=0x7000。
//*****************************************************************************

定時(shí)器1用于波特率發(fā)生器
//*****************************************************************************
//初值計算公式：
// TH1=256-(2^SMOD/32*Fosc/12*1/Bound)
// 其中：SMOD=0，1；Fosc=晶體或晶振頻率；Bound=波特率
// 本例中，SMOD=0；Fosc=21.1184MHz；Bound=19200，所以TH1=0xFD。
//*****************************************************************************

demo程序項目中增加按如上方法改寫(xiě)的startup.a51后，在我的用戶(hù)板硬件上運行正確。

為uCOS51增加Shell界面：
uCOSII只提供了操作系統內核，用戶(hù)要自己添加文件處理、人機界面、網(wǎng)絡(luò )接口等重要部分。其中Shell(人機界面)提供了人與機器交互的界面，是機器服務(wù)于人的體現，是系統必不可少的重要組成部分?，F代的很多OS如UNIX、DOS、VxWorks都提供了友好的命令行界面。Windows更是提供了GUI。大部分人認識OS都是從這里開(kāi)始的。uCOS51同樣擁有Shell，它是我從以前寫(xiě)的前后臺程序中移植過(guò)來(lái)的。

命令行Shell的工作原理比較簡(jiǎn)單，主要思路就是單片機接收用戶(hù)鍵盤(pán)輸入的字符存入命令緩沖區，并回顯到屏幕，當用戶(hù)按下回車(chē)鍵，觸發(fā)軟件狀態(tài)機狀態(tài)變遷，從輸入態(tài)轉移到命令解釋?xiě)B，然后根據用戶(hù)命令調用相關(guān)子程序執行相應操作，執行完畢后重新回到輸入態(tài)。
我感覺(jué)原理很好掌握，程序也不長(cháng)，但是細節部分要反復調試多次才能穩定工作。比如：命令行左右邊界的保護、退格鍵的處理、詞表的設計等等。
Shell程序由詞表、取詞子程序、狀態(tài)機框架程序(輸入回顯和命令解釋執行)、命令相關(guān)子程序組成(詳見(jiàn)源程序清單)。
詞表結構如程序清單所示，由詞數目，左括號數，右括號數，每個(gè)詞的具體信息（長(cháng)度，字符串）構成。左右括號數用于括號匹配檢查；詞數目用于程序循環(huán)；詞的具體信息作為解釋/執行程序的輸入參數。
取詞子程序從命令行語(yǔ)句中提取單詞并存入詞表同時(shí)進(jìn)行匹配檢查和詞法分析。默認字符為：0-9、a-z、A-Z、'.'；定界符為：空格、逗號，左/右括號。建議用戶(hù)補充默認字符集(? / -)以便實(shí)現更靈活的語(yǔ)法。注意：現在版本的Shell只檢查左右括號數量的匹配，無(wú)優(yōu)先級和語(yǔ)法含義。
輸入回顯程序循環(huán)檢查用戶(hù)鍵盤(pán)輸入。如果輸入回車(chē)，程序狀態(tài)轉入解釋執行態(tài)；如果輸入退格(8)則回顯退格、空格、退格，模擬刪除字符，同時(shí)輸入緩沖區清除相應字節，清除前先檢查左邊界是否越界。如越界則鳴響報警且不執行清除操作；其他字符輸入直接存入輸入緩沖區并回顯，此前檢查右邊界是否溢出，如果溢出則鳴響報警且拋棄剛輸入的字符。
命令解釋程序調用取詞子程序分析用戶(hù)命令行輸入，根據詞表第一個(gè)單詞在散轉表中的位置調用相應執行子程序處理命令，如果散轉表中無(wú)此單詞，則打印“Bad command！”。取詞子程序返回錯誤指示時(shí)也打印此句。
命令解釋程序向相應的命令相關(guān)子程序傳入詞表指針，具體執行由用戶(hù)自行決定。由命令相關(guān)子程序返回后重新回到命令輸入態(tài)，完成一次輸入執行全過(guò)程。此過(guò)程周而復始地循環(huán)執行。

Shell界面的命令按功能分為以下幾組：
1。操作系統相關(guān)命令：
查看就緒任務(wù)l(shuí)t / 中止任務(wù)kill / 恢復任務(wù)執行call / CPU利用率usage / 版本查詢(xún)ver / 查某個(gè)任務(wù)信息(TCB、堆棧內容)lt
查看切換次數和時(shí)間lts

2。網(wǎng)絡(luò )相關(guān)命令：
顯示配置MAC地址macadr / 顯示配置主機IP地址host / 顯示配置子網(wǎng)掩碼mask / 顯示配置缺省網(wǎng)關(guān)gateway
顯示網(wǎng)絡(luò )配置總情況lc / 連通測試命令ping / 用戶(hù)數據報發(fā)送命令udp / telnet命令tel / 相關(guān)應用命令**
顯示ARP高速緩沖區地址對ls / 顯示發(fā)送緩沖區信息lti

3。屏幕顯示相關(guān)命令：
清屏clr / 幫助help / 功能鍵F3、F7處理 / 組合鍵Ctrl+C、Ctrl+B處理

4。外設(閃盤(pán)X5045和I/O口)相關(guān)命令：
讀閃盤(pán)rdx / 讀I/O口rdp / 寫(xiě)閃盤(pán)wdx

5。安全相關(guān)命令：
身份認證密碼權限usr、pass

6。應用相關(guān)命令：
用戶(hù)自行定義

用戶(hù)命令大小寫(xiě)不敏感，程序將命令字符串統一成小寫(xiě)形式。程序中各種參數(如：最大詞長(cháng)度、詞數量……)定義成宏放在一個(gè)頭文件中，隨時(shí)可修改配置，很方便。Shell作為一個(gè)任務(wù)工作于內核之外，占用一個(gè)任務(wù)號。

源程序：
詞表
typedef struct{
int Num;
int LeftCurveNum,RightCurveNum;
struct{
int Length;
unsigned char Str[MaxLenWord+1]; /*for '国产精品自在自线亚洲|国产精品无圣光一区二区|国产日产欧洲无码视频|久久久一本精品99久久K精品66|欧美人与动牲交片免费播放